Softwarová Záchrana 3/Softwarova-zachrana-3.bin/Xteq X-Setup/xqdcXSP-Setup-EN.exe/{app}/plugins/XQ MSOXP MRU 1.xpl

Text File | 2004-01-29 | 6KB | 182 lines

"FILE"="Xteq Systems X-Setup Plugin 6.0"
"TYPE"="8"
"COUNT"="3"
"UIPATH"="Program Options\Microsoft Office\MS Office XP\Open/Save Dialog\Action MRU"
"NAME"="Action MRU lists"
"VERSION"="1.02"
"LANGUAGE"="VBScript"
"TEXT 1"="View..."
"TEXT 2"="Clear MRU..."
"TEXT 3"="CLEAR ALL"
"DESCRIPTION 1"="When an Office program requests you about a filename to save or load, it will save this filename into a list called Most Recent Used (MRU). Basically, this list is the same as the "Documents" list inside your Start Menu but Office goes beyond a simple list."
"DESCRIPTION 2"="In each program, you can perform several tasks with a file. For example, in Word you can either open a document which will ask you for a filename, but you can also enter a graphic file into your current document and thus you have two different actions "File Open" and "Insert Graphic"."
"DESCRIPTION 3"="Each Office program can execute several actions and a most recent used files list is retained for each action. "
"DESCRIPTION 4"="Simply select the program you are interested in and click on "View" to see the available actions and the associated files. "
"DESCRIPTION 5"="Click on "Clear" to clear all linked files (MRU) for the selected application. Click on "Clear All" to clear ALL linked files in ALL MRUs in ALL found Office Programs."
"DESCRIPTION 6"="Note: Clearing the MRU list does _NOT_ delete the files, the plug-in will simply remove the file "link" from the registry. Your files will of course not be deleted. "
"AUTHOR"="Xteq Systems"
"CONTACTURL"="http://www.xteq.com/"
"COPYRIGHT"="Copyright ⌐ Xteq Systems - All Rights Reserved"
"COMMENT 1"="see http://support.microsoft.com/?scid=312968"


'*******************************************
'* ORIGINAL FILE IS <XQ MSOXP MRU 1.xpl>  **
'*******************************************


sP_Check="HKCU\Software\Microsoft\Office\10.0\"
      sP="HKCU\Software\Microsoft\Office\10.0\Common\Open Find\"

sV_Settings="\Settings\"
sV_MRU="\File Name MRU\Value"

sV_MS="Microsoft"

Dim iCount
Dim aryLoc()

Sub Plugin_Initialize
 if RegPathExists(sP_Check) then
    Call RefreshDisplay()
 else
    Call Disable()
 end if
End Sub


Sub Plugin_Apply(ElementIndex,ElementSubIndex)
 if ElementSubIndex<0 then
    Call MsgError("Please select an item first!")
 else
    ESI=ElementSubIndex
    sPrgName=aryLoc(ESI)
    sTMPPath=sP & sPrgName & sV_Settings

    If ElementIndex=1 then
       iCnt=RegEnumPaths(sTMPPath)
       sMsg="The following files are saved for each action listed in the selected program. Please note that the listing of files will be stopped after three files, even if more exist." & chr(13) & chr(10) & chr(13) & chr(10)

       for l=1 to iCnt
           sActionName=RegEnumElement(l)

           'WHOEVER HAD THE IDEA OF THIS REGISTRY KEY: I HATE YOU !!!
           sTMPPAth=sP & sPrgName & sV_Settings & sActionName & sV_MRU

           'find some files in the current action
           temp_ary=RegReadValue(sTMPPath)
           sFiles=""

           if IsEmpty(temp_ary)=false then
              for e=lbound(temp_ary) to ubound(temp_ary)
                  sFiles=sFiles & temp_ary(e) & "; "
                  if e=2 then exit for
              next
           end if

           if len(sfiles)=0 then
              sFiles="No Files"
           else
              sFiles="(Files: " & sFiles & ")"
           end if

           sMsg = sMsg & "[" & sActionName & "] " & sFiles & chr(13) & chr(10)
       next

       Call MsgInformation(sMsg)
    end if


    'KILL ONE MRU!
    If ElementIndex=2 then
       Call TrashMRUEntries(sTMPPath,sPrgName)

       Call MsgInformation("File entries removed, please click the View button to check the changes.")
       'Call RefreshDisplay
   end if
 end if


 'for clear all, the user does not need to have an item selected

 '---CLEAR ALL !!!! ----
 If ElementIndex=3 then
    sReturn=InputWindow("Are you really sure you want to clear MRU entires? If so, please enter YES and click OK.","YES",1)
    if IsEmpty(sReturn)=false then

       for l=lbound(aryLoc) to ubound(aryLoc)
           sPrgName=aryLoc(l)
           sTMPPath=sP & sPrgName & sV_Settings

           if EntryIsOfficePrg(sPrgName) then
              'okay, this is a program
              Call TrashMRUEntries(sTMPPath,sPrgName)
           end if
       next

       Call MsgInformation("All file entries removed, please click the View button to check the changes.")

    end if
 end if



End Sub


Sub RefreshDisplay
 For l=1 to iCount
     Call SetUIElement(l,"")
 next

 iCount=RegEnumPaths(sP)

 if iCount>0 then
    'redim array
    ReDim aryLoc(iCount)

    for l=1 to iCount
        s=RegEnumElement(l)
        aryLoc(l)=s
    next

    for l=lbound(aryLoc) to ubound(aryLoc)
        s=aryLoc(l)

        if EntryIsOfficePrg(s) then
           'okay, this is a program
           sTMPPath=sP & s & sV_Settings
           iCntActions=RegEnumPaths(sTMPPath)

           Call SetUIElement(l,s & " (" & CStr(iCntActions) & " actions)")
        end if
    next
 end if
End Sub

Function EntryIsOfficePrg(RegEntryName)
 if ucase(left(RegEntryName,len(sV_MS)))=ucase(sV_MS) then
    EntryIsOfficePrg=true
 else
    EntryIsOfficePrg=false
 end if
End Function


Sub TrashMRUEntries(TMP_Path,PRG_NAME)
    iCnt=RegEnumPaths(TMP_Path)

    for l=1 to iCnt
        sActionName=RegEnumElement(l)
        sTMPPAth=sP & PRG_Name & sV_Settings & sActionName & sV_MRU

        if RegValueExists(sTMPPath) then
           Call RegDeleteValue(sTMPPath)
        end if
     next
End Sub


Sub Plugin_Terminate
End Sub